背景

Nix-on-Droidとは

nix-community/nix-on-droidは、 Termuxベースの環境にNixとhome-managerを組み込んで、 Android端末でNixパッケージとhome-manager設定を使えるようにするプロジェクトです。

systemd-nspawnのようなコンテナでもなく、 AndroidのLinuxサブシステムでもなく、 prootというユーザーランドエミュレーションのレイヤの上でNixが動いています。

NixOSモジュールは使えませんが、 home-managerはそのまま使えるので既存のdotfiles設定をほぼ流用できます。

事前準備

実装

feat: TermuxベースのNix-on-Droidで動作 by ncaq · Pull Request #498 · ncaq/dotfiles

nix-on-droid = {
  url = "github:nix-community/nix-on-droid/release-24.05";
  inputs = {
    nixpkgs.follows = "nixpkgs";
    home-manager.follows = "home-manager";
  };
};

nix-on-droid.lib.nixOnDroidConfiguration {
  inherit pkgs;
  modules = [
    {
      system.stateVersion = "24.05";
      nix.extraOptions = ''
        experimental-features = flakes nix-command
      '';
      environment = {
        etcBackupExtension = ".bak";
        # Tailscale前提のDNS設定。
        etc."resolv.conf".source = ./resolv.conf;
      };
      android-integration = {
        am.enable = true;
        termux-open.enable = true;
        termux-open-url.enable = true;
        xdg-open.enable = true;
        # ...
      };
      terminal.font = "${pkgs.firge-nerd-font}/share/fonts/firge-nerd/FirgeNerdConsole-Regular.ttf";
      # Androidホストのタイムゾーンは自動的に引き継がれないので明示的に設定。
      time.timeZone = "Asia/Tokyo";
      user.shell = "${pkgs.zsh}/bin/zsh";
      home-manager = {
        extraSpecialArgs = {
          isTermux = true;
          isWSL = false;
          # ...
        };
        config = ../home;
      };
    }
  ];
  home-manager-path = home-manager.outPath;
}

if !isTermux then
  {
    services.gpg-agent = {
      enable = true;
      enableSshSupport = true;
      pinentry.package = pkgs.pinentry-qt;
      sshKeys = [ sshKeygrip ];
    };
  }
else
  {
    programs.zsh.initContent = ''
      export GPG_TTY=$(tty)
      gpgconf --launch gpg-agent
      export SSH_AUTH_SOCK=$(gpgconf --list-dirs agent-ssh-socket)
    '';
    home.file.".gnupg/gpg-agent.conf".text = ''
      enable-ssh-support
      pinentry-program ${pkgs.pinentry-curses}/bin/pinentry-curses
    '';
    home.file.".gnupg/sshcontrol".text = ''
      ${sshKeygrip}
    '';
  }

home.activation.sops-nix = lib.mkForce (
  lib.hm.dag.entryAfter [ "writeBoundary" ] ''
    export XDG_RUNTIME_DIR="${cfg.defaultSecretsMountPoint}"
    export SOPS_GPG_EXEC="${cfg.gnupg.package}/bin/gpg"
    $DRY_RUN_CMD ${sops-install-secrets}/bin/sops-install-secrets -ignore-passwd ${manifest}
  ''
);

# gitがPATHにない場合gitをPATHに追加して再実行。
if ! command -v git &>/dev/null; then
  exec nix shell 'nixpkgs#git' --command "$0" "$@"
fi

if [ -f /etc/NIXOS ]; then
  sudo nixos-rebuild switch --flake ".#$(hostname)"
elif [ -n "${TERMUX_VERSION:-}" ]; then
  nix-on-droid switch --flake "."
else
  # ...
fi

tmuxのAndroid向け調整

feat(tmux): Tmuxのネストトグルキーを変更 by ncaq · Pull Request #537 · ncaq/dotfiles

tmuxの設定をAndroidフレンドリーにする · Issue #530 · ncaq/dotfiles

実際にAndroidで使ってみると、 tmuxのネストトグルキー(F12など)がAndroidのソフトウェアキーボードでは押しにくいことが分かりました。 AndroidでSSHする場合はほとんどの操作がサーバ側のtmuxで完結するため、 Androidで押しやすいキーに変更しました。

sops-nixインストール時の問題修正

fix: Nix-on-Droid環境でインストールする時にsops-nixが失敗することを再回避 by ncaq · Pull Request #595 · ncaq/dotfiles

新しい端末などで改めてインストールする際に、 sops-nixのactivation hookがDAGの関係で正しく実行されない問題がありました。 entryAfter [ "writeBoundary" ]を適切に設定して修正しました。

Claude Codeについて

本来の目的のひとつがClaude CodeをAndroidから使うことでした。実際に試してみると、 prootエミュレーションとの相性か何かでClaude Codeはうまく動きませんでした。

本家Termuxなら動いたという記事があるので動作自体は可能なようです。今回のNix-on-Droidはprootベースなので、そこが原因かもしれません。

ただそもそもスマートフォンで開発するにしても、 Snapdragon 8 EliteのCPU性能は十分としても、端末の16GBメモリよりサーバの64GBメモリで作業した方が快適です。なのでClaude Codeはサーバ側で動かすという運用に落ち着きました。

感想

Nix-on-Droidを使ってみて、既存のhome-manager設定をisTermuxフラグで分岐するだけで、ほぼそのまま流用できたのは思ったより楽でした。

特にGPGエージェント経由のSSH認証がそのまま使えたのは大きいです。 GPGの認証サブキーはSSHの秘密鍵とは仕組みが異なるため、 OpenSSHクライアントを直接使えない環境では認証が面倒になりがちです。 Nix-on-DroidではOpenSSHをそのまま使えるので、 gpg-agentをSSH_AUTH_SOCKに設定するだけで完全に動作しました。

まとめ

Nix-on-Droidをセットアップし、 AndroidをNix環境込みのSSHクライアントにしました。

• ConnectBot等は楕円曲線暗号のGPG認証鍵に対応していないのでNix-on-Droidを選択
• isTermuxフラグで既存のhome-manager設定を分岐して流用
• systemdがない環境でgpg-agentをzshから起動してSSH認証を実現
• sops-nixのactivation hookを直接実行方式に置き換え

セットアップ後にClaude Codeの公式リモートコントロール機能が発表されたので、今後そのUX次第ではこの方法の役割が変わるかもしれません。とはいえNix環境がAndroidで使えること自体は便利です。端末を買い替えた際もinstall.sh一発で環境が再現できるのは継続して有用です。

主なソースコードはncaq/dotfilesにあります。